Re : Minim and Real Memory / Memory

As PhiLho said. Perhaps you need some println()'s cause there are two options and both are no good. Either you don't close samples as I assumed (because each sample never stops playing, in fact it's replaced before it ends). Or you do close each sample, but then you also stop minim and the sketch, which is strange, because you keep using it.

To answer your question. You only need to close a sample when you are done with it. You only need to stop Minim when you are done with the whole sketch.

In addition, I suggest moving to Processing 2.01 where you don't need to stop Minim anymore so I suspect some changes have been made in the past years also to the included core version of Minim.

Furthermore I find it very peculiar that there would be a 32 limit on playable files. I've written a test sketch - tested with Processing 2.01's Minim - and I encounter no such problems. I can load all 42 mp3s and play each one of them.

Again, all the code you posted so far has seemed buggy. So I would check twice before your blame it on the library.

Code Example (Processing 2.01)

1. // press space to go to the next file
   
2. 
   
3. import ddf.minim.*;
4.  
5. String pathToMp3s = "C:/Media/Music/Collected/"; // contains 42 mp3s of in total 324 MB
6.  
7. Minim minim;
8. AudioPlayer[] mp3s;
9. String[] filenames;
10. int count;
11.  
12. void setup() {
13.   size(300, 300);
14.   minim = new Minim(this);
15.  
16.   filenames = loadFilenames(pathToMp3s);
17.   mp3s = new AudioPlayer[filenames.length];
18.  
19.   for (int i=0; i<mp3s.length; i++) {
20.     mp3s[i] = minim.loadFile(pathToMp3s + filenames[i]);
21.   }
22.  
23.   mp3s[0].play();;
24.   println("Number 0 (" + filenames[0] + ") is currently playing.");
25. }
26.  
27. void draw() {
28.   background(0);
29. }
30.  
31. void keyPressed() {
32.   if (key == ' ') {
33.     for (int i=0; i<mp3s.length; i++) {
34.       if (mp3s[i].isPlaying()) mp3s[i].pause();
35.     }
36.     count = ++count%mp3s.length;
37.     mp3s[count].play();
38.     println("Number " + count + " (" + filenames[count] + ") is currently playing.");
39.   }
40. }
41.  
42. String[] loadFilenames(String path) {
43.   File folder = new File(path);
44.   java.io.FilenameFilter filenameFilter = new java.io.FilenameFilter() {
45.     public boolean accept(File dir, String name) {
46.       String lowcase = name.toLowerCase();
47.       return lowcase.endsWith(".mp3");
48.     }
49.   };
50.   return folder.list(filenameFilter);
51. }